BImage map;
BFont font;
Zone[] zoneArray;
float x_min, y_min, x_max, y_max;
float[] xArray; //stores x gps coords (longitude)
float[] yArray; //stores y GPS coords (latitude)
float[] currentX;
float[] currentY;
int xCnt, yCnt; //individually count x and y coordinates
int id; //variable path (unique)
int numZones;
boolean display, displayZones, paused; //to display path
int j, e; //counters
float usrX, usrY;
String currentLocation;
BImage currentPic;
float picX, picY;

/********************************************
* place authored points here or grab from a database
*********************************************/

void setup()
{
  size(511, 684);
  map = loadImage("losFeliz.jpg");
  font = loadFont("VT100_Bold.vlw");
  //for db stuff
  xArray = new float[10000]; // limit 10000 points
  yArray = new float[10000];
  currentX = new float[10000]; // limit 10000 points
  currentY = new float[10000];
  zoneArray = new Zone[10000];
  e=0;
  xCnt = 0;
  yCnt = 0;
  //id = Integer.parseInt(param("path_id")); //set a path - I think we can get this from the param function in processing // id = 121 is current path
  id = 122;  //or hard code it for non-applet viewing
  j=0;
  display = false;
  displayZones = false;
  paused = false;

  //define boundaries
  x_min = -118.296146;
  y_min = 34.112269;
  x_max = -118.285229;
  y_max = 34.099938;

  delay(1000);
  loadZones();
  delay(2000);
  loadPath();

}

void loop()
{
  background(255);
  imageMode(CORNER);
  image(map, 0, 0);
  stroke(255, 250, 50);
  fill(255, 250, 50);
  
  if (displayZones) {
    for(int z=0; z<numZones; z++) {
      zoneArray[z].display();
    }
  }
  
  if(display) {
    if(j<(xCnt+yCnt)/2) {
      //println(xArray[j] + ", " + yArray[j]);
      if(!paused) {
        usrX = gpsx2pixel(xArray[j]);
        usrY = gpsy2pixel(yArray[j]);
        //println(x + " " + y);
        rect(usrX, usrY, 5, 5);
        currentX[j] = usrX;
        currentY[j] = usrY;
        j++;
      }
      for(int n=0; n<j; n++) {
        stroke(255, 250, 50, 100);
        fill(255, 250, 50, 100);
        rect(currentX[n], currentY[n], 5, 5);
        line(usrX, usrY, gpsx2pixel(xArray[j-1]), gpsy2pixel(yArray[j-1]));
      }
    } else {
      j=0;
      for(int z=0; z<numZones; z++) {
        zoneArray[z].hit = false;
      }
    }
  } 
  
}

void mousePressed() 
{  
  paused = false;
}

float gpsx2pixel(float longitude) {
  float x = ((longitude - x_min)/(x_max - x_min)) * width;
  return x;
}
float gpsy2pixel(float latitude) {
  float y = ((latitude - y_min)/(y_max - y_min)) * height;
  return y;
}

void loadPath(){
  try {
    InputStream input = loadStream("http://www.patholog.org/upload/final/gps.php?id=" + id); //read db values via via php text output
    InputStreamReader isr = new InputStreamReader(input);
    BufferedReader reader = new BufferedReader(isr);

    String path; //String that holds the entire coordinates, all separated by a comma

    while ((path = reader.readLine()) != null) {
      String[] parsedPath = splitStrings(path, ',');
      for(int i=0; i<parsedPath.length; i++) {
        if((i%2) == 0) {
          float x2float = Float.parseFloat(parsedPath[i]);
          xArray[xCnt] = x2float;
          xCnt++;
        } else {
          float y2float = Float.parseFloat(parsedPath[i]);
          yArray[yCnt] = y2float;
          yCnt++;
        }
      }
    }

    display = true;

  } catch(Exception e) {
    println("error reading stream: "+e.getMessage());
  }

}

void loadZones(){
  try {
    InputStream input = loadStream("http://www.patholog.org/upload/final/zones.php"); //read db values via via php text output
    InputStreamReader isr = new InputStreamReader(input);
    BufferedReader reader = new BufferedReader(isr);

    String zones; //String that holds the entire coordinates in the format x,y,location;x2,y2,location2; ...

    while ((zones = reader.readLine()) != null) {
      String[] parsedZones = splitStrings(zones, ';'); //Split into an array of just the locations
      numZones = parsedZones.length;
      for(int i=0; i<parsedZones.length; i++) {
        zoneArray[i] = new Zone(parsedZones[i], i);
      }
    }
  displayZones = true;

  } catch(Exception e) {
    println("error reading stream: "+e.getMessage());
  }

}

class Zone
{
  int id;
  float x, y;
  String data, location, img;
  float d;
  boolean hit;
  BImage pict;

  Zone(String DATA, int ID) {
    id = ID;
    data = DATA;
    String[] parse = splitStrings(data, ',');
    for(int j=0; j<parse.length; j++) {
      if(j==0) { x = Float.parseFloat(parse[j]); } if(j==1) { y = Float.parseFloat(parse[j]); } 
      if(j==2) { location = parse[j]; } if(j==3) { img = "http://www.patholog.org/upload/will/p5test/thumbnails/" + parse[j]; }
    }
    pict = loadImage(img);
    println(x + ", " + y + ", " + location + " " + img);
    //translate to pixel space
    x = gpsx2pixel(x);
    y = gpsy2pixel(y);
    hit = false;
  }

  void display() {
    ellipseMode(CENTER_RADIUS);
    noStroke();
    fill(0, 255, 255, 150);
    ellipse(x, y, 2, 2);
    check(usrX, usrY);
    if(d<20 && !hit) {
      fill(0, 0, 0);
      textFont(font, 36);
      text(location, 10, 40);
      image(pict, x, y);
    }
  }
  
  void check(float xVal, float yVal) {
    d = dist(x, y, xVal, yVal);
  }

}